TRstar.NET | Mirc indir

Bu hazır kod ile belirtmiş olduğunuz yazıyı tersten yazdırmış olursunuz. Aşağıda ki mevcut kodu Mirc Remote kısmına kopyalayıp, ” //echo -a $yazi(metin yazınız).cevir ” komutunu uygulayınız.

(daha fazla…)

Bu hazır kod ile değişik tuşlar ile kanal içinde ki ban haraketleri üzerinde işlem yaptırabilirsiniz. ” Ctrl + f8 ” tuşlarını bastığınız gibi kanalda ki en son atmış olduğunuz banlardan 5 tanesi kaldırmış olursunuz. ” shift + f8 ” tuşları ile kanalda ki en son verilen nickin banlarından 5 tanesini kaldırmış olursunuz. ” F8 ” tuşu ile kanalda atılan en son banlardan 15 tanesi kaldırırsınız. Ayrıca kanalın ban listesi 30 u geçtiği gibi atılan son 15 banı oto kaldırmış olur. Aşağıda ki kodu mirc remote bölümünüze yazmanız gerekir.

[code]tub = total unban
alias tub {
if $1 !ischan || !$2 { /echo $color(info text) -at * /tub: insufficient parameters | halt }
if $me isop $1 || $me ishop $1 {
var %i = $ibl($1,0), %items = $iif($calc($ibl($1,0) - $2) < 0,$ibl($1,0),$2), %modespl = $null
if !$hget($+($1,-ibl)) { hmake $+($1,-ibl) %items }
while $hget($+($1,-ibl),0).item < %items {
if $3 { if $gettok($ibl($1,%i).by,1,33) == $3 { hadd $+($1,-ibl) $ibl($1,%i) $ibl($1,%i).ctime $gettok($ibl($1,%i).by,1,33) } }
else { hadd $+($1,-ibl) $ibl($1,%i) $ibl($1,%i).ctime }
dec %i 1
if %i <= 0 { break }
}
%i = $hget($+($1,-ibl),0).item
while %i {
if $calc($count(%modespl,$chr(32)) + 1) >= $modespl { .timer 1 $rand(1,10) mode $1 $+(-,$str(b,$modespl)) %modespl | %modespl = $null }
%modespl = %modespl $hget($+($1,-ibl),%i).item
dec %i 1
}
if %modespl { .timer 1 $rand(1,10) mode $1 $+(-,$str(b,$calc($count(%modespl,$chr(32)) + 1)))) %modespl }
hfree $+($1,-ibl)
}
}
on *:op:#: { if $opnick == $me && !$chan($chan).ibl { set %ibl $true | mode $chan +b } }
on *:halfop:#: { if $hopnick == $me && !$chan($chan).ibl { set %ibl $true | mode $chan +b } }
raw 367:*: { if %ibl { halt } }
raw 368:*: { if %ibl { unset %ibl | halt } }
on *:ban:#: { if $ibl($chan,0) >= 30 { /tub $chan 15 } }
alias F8 { if $active ischan { tub $active 15 } }
alias CF8 { if $active ischan { tub $active 5 $me } }[/code]

Duration identifiers ‘e benzer kullanımı ve işlevi vardır. Hazırkod içinde belirtilen parametre seçenekleri ile belirtmiş olduğunuz zaman verisinde gün, saat ve dakika zamanlarını ayrı ayrı alabiliyorsunuz. Mirc Remote bölümüne aşağıda ki kodu kopyalamanız yeterlidir.

Kullanımı : $dur(saniye)
Properties : days, hours, minutes
Örnek : ” //echo -a $dur(1258745) ” komutunu uyguladığınızda “ 1258745 ” saniyenin ” 14 days, 13:39 ” zaman birimine eşit olduğunu görürüz. Buda 14 gün 13 saat ve 39 dakika olduğunu söyler.

Örnek : ” //echo -a $dur(1258745).hours ” komutunu uyguladığınızda ” 13 ” verisini alırız. Burada gün ve dakika harici sadece saatin gösterilmesini sağlamış olursunuz.

Code;

[code]ALIAS dur {
var %uptime.days = 0, %uptime.time
if ($regex($duration($1),/(\d+)wk/)) { %uptime.days = $calc($regml(1) * 7) }
if ($regex($duration($1),/(\d+)day/)) { inc %uptime.days $regml(1) }
var %uptime.dummy1 = $regex(hr,$duration($1),/(\d+)hr/), %uptime.dummy2 = $regex(min,$duration($1),/(\d+)min/)
%uptime.time = $+($iif($regml(hr,0),$iif($len($regml(hr,1)) == 1,$+(0,$regml(hr,1)),$regml(hr,1)),00),:,$iif($regml(min,0),$iif($len($regml(min,1)) == 1,$+(0,$regml(min,1)),$regml(min,1)),00))
if ($prop == days) return %uptime.days
if ($prop == hours) return $gettok(%uptime.time,1,58)
if ($prop == minutes) return $gettok(%uptime.time,2,58)
else { return %uptime.days $+(day,$iif(%uptime.days > 1,s),$chr(44)) %uptime.time }
}
[/code]

Bu Hazır kod ile girmiş olduğunuz rakamı dakika ve saniye olarak verir. Aşğıda ki kodu mirc Remote bölümünüze kopyalamanız gerekir.

Kullanımı : //echo -a $timeconv(zaman)
Örnek : //echo -a $timeconv(500) komutu ile ” 8:20 ” cevabını almış olursunuz. Buda 8 dakika 20 saniye anlamına gelir.

[code]alias timeconv {
var %b = $calc($1 / 60),%a = $calc($gettok(%b,2,46) / 100 * 60),%c = $gettok(%b,2,46)
return $gettok(%b,1,46) $+ : $+ $iif($len(%a) > 3,$iif($len(%a) < 8,0) $+ $round($left(%a,$iif($len(%a) < 8,1,2)) $+ . $+ $right(%a,-2),1),$iif($len($remove(%a,.)) < 2,$iif($left(%c,1) == 5,$remove(%a,.) $+ 0,0 $+ $remove(%a,.)),$remove(%a,.)))
}[/code]

[code];kanalda yazılan mesaj kısmı özelede yazılabilir rahatlıkla
on *:text:*:#: {
  if $noflood($+($chan,-,$nick),selam) && ($regex($1-,sell*amm*) || $regex($1-,slm) || $regex($1-,s\.a$) || $regex($1-,s\.a\.)) {
    if $regex($1-,(nass*ıll*ss*ınn*)|(nass*ill*ss*ınn*)|(nass*ıll*ss*inn*)|(nass*ill*ss*inn*)|(nass*ıı*nn*)|(nass*ii*nn*)) && $noflood($+($chan,-,$nick),nassin) {
      msg $chan selam $nick $+ . iyiyim sen nasılsın
    }
    else { msg $chan selam }
  }
  if $regex($1-,(nass*ıll*ss*ınn*)|(nass*ill*ss*ınn*)|(nass*ıll*ss*inn*)|(nass*ill*ss*inn*)|(nass*ıı*nn*)|(nass*ii*nn*)) && $noflood($+($chan,-,$nick),nassin) {
    msg $chan $nick iyiyim sen nasılsın?
  }
  if ($regex($1-,asl .*) || $regex($1-,^asl$)) && $noflood($+($chan,-,$nick),asl) { msg $chan ne yapacaksın asl yi? }
}

;whois kısmı
on $*:snotice:/\/whois on you.$/Si: {
  if $noflood($+(whois-,$2),whois) {
    .notice $2 0,2Buyrun Nasıl Yardımcı oLabiLirim ? KişiseL Sohbet İçin Lütfen ÖzeLimi Meşgul Etmeyin.Yardım ALmak İçin #operheLp KanaLından OnLine OperLere ULaşabiLirsiniz..KEYİFLİ SOHBETLER..
  }
}

on *:nick: {
  noflood pid $nick $newnick
  var %i = $chan(0)
  while %i {
    noflood pid $+($chan(%i),-,$nick) $+($chan(%i),-,$newnick)
    dec %i 1
  }
}
;noflood(nick,text) pid kullanıldı böylece nick değiştimi işlemimiz kısa sürecek
alias noflood {
  if !$timer(NFLD) { .timerNFLD 0 60 /noflood timer }
  if !$hget(PID-NFLD) { hmake PID-NFLD 70 }

  if $isid {
    if !$hget(PID-NFLD,$1) { hadd PID-NFLD $1 $+($ctime,$rand(0,99)) }
    var %PID = $hget(PID-NFLD,$1)

    if !$hget($+(NFLD-,%PID)) { hmake $+(NFLD-,%PID) 50 | hadd $+(NFLD-,%PID) ctime $ctime }
    if $hmatch($+(NFLD-,%PID),$replace($2,$chr(32),$chr(160)),0) { return $false }
    else { hadd $+(NFLD-,%PID) $replace($2,$chr(32),$chr(160)) $ctime | hadd $+(NFLD-,%PID) ctime $ctime | return $true }
  }

  else {
    if $regex($1-,^timer$) {
      var %i = $hget(0)
      while %i {
        if $regex($hget(%i),^NFLD-.*) {
          if $calc($ctime - $hget($hget(%i),ctime)) > 1200 { hfree $hget(%i) }
        }
        dec %i 1
      }
    }

    if $regex($1,^pid$) && $2 && $3 {
      if $hget(PID-NFLD,$2) {
        hadd PID-NFLD $3 $v1
        hdel PID-NFLD $2
      }
    }
  }
}[/code]

Basit bir digital saat uygulaması ek olarak tarih ve günüde veriyor

INDIR

[code]alias temizle {
var %y $+(.,?) , %yi
if $numtok($1-,32) == 1 {
var %1kelime 1
}
%yi = $replace($1-,$chr(42),%y,$chr(36),%y,$chr(91),%y,$chr(93),%y,$ chr(92),%y,$chr(47),%y,$chr(43),%y,$chr(63),%y,$ch r(94),%y,$chr(124),%y,$chr(40),%y,$chr(41),%y,$chr (164),%y,$chr(33),%y,$chr(123),%y,$chr(125),%y,$ch r(189),%y,$chr(188),%y,$chr(39),%y,$chr(46),%y,$ch r(44),%y,$chr(60),%y,$chr(61),%y,$chr(62),%y,$chr( 34),%y,$chr(199),%y,$chr(221),%y,$chr(58),%y,$chr( 45),%y,$chr(254),%y,$chr(222),%y,$chr(32),%y)
if %1kelime {
%yi = $+(^,%yi,$chr(36))
}
return $iif($len($remove(%yi,.,*)) > 5,%yi,SPAMKONTROLUNDEGECERSIZ aslolan mesaj: $1- )
}
on *:open:?:{
set -u5 %nickw. [ $+ [ $nick ] ] warn
}
alias spch {
if (!$window(@Spams)) window -ne @Spams
spamekle $temizle($2-)
echo -t @Spams $1 : $temizle($2-)
}
on *:text:*:?:{
if (!%nickw. [ $+ [ $nick ] ]) { halt }
if (%nickw. [ $+ [ $nick ] ] == warn) && (*_* iswm $1-) && ($right($1,1) isnum) && ($2 == $null) { spch $nick $1 }
var %t = 1 , %kelime = $gettok($strip($1-),0,32)
var %cümle = $strip($1-)
if (%kelime == 2) && ($len($strip($1)) >= 5) && ($strip($2) == @) { spch $nick $1- }
while (%t <= %kelime) {
set %ara $gettok($strip($1-),%t,32)
if ($v1 == 1) && ($right(%ara,1) == @) || ($right(%ara,2) == @h) || ($right(%ara,3) == @hot) { spch $nick %ara }
if (*_* iswm %ara) && ($right(%ara,1) isnum) { spch $nick %ara }
if ($right($gettok(%ara,1,64),1) isnum) && (@ isin %ara) { spch $nick %ara }
if (%nickw. [ $+ [ $nick ] ] == warn) && (%ara == @) { spch $nick $gettok($strip($1-),$calc(%t - 1),32) %ara $gettok($strip($1-),$calc(%t + 1),32)) }
if (*@h?* iswm %ara) { spch $nick %ara }
if ($right($gettok($strip($1-),$calc(%t - 1),32),1) isnum) && (*h?t* iswm %ara) { spch $nick $gettok($strip($1-),$calc(%t - 1),32) %ara }
inc %t 1
}
}
alias spamekle {
spamfilter add cNnpa gzline +7200 Spam! $1-
}
alias spamsil {
spamfilter del cNnpa gzline +7200 Spam! $1-
}[/code]

Gelen Mesaj : [14:35] ayse18evde@hot ekle
Eklenen Spam : [14:35] .?.?ayse18evde@hot.?.?.

“alıntidir” Kod için, xcLusive‘e teşekkürler.

Bu hazır kod ile Windows işletim sistemi ile ilgili bazı özel klasörlerin bulunduğu yerlerini öğrenmiş olursunuz. Aşığıda hangi özel klasörler hakkında bilgi alabileceğinizi görebilirsiniz. Kullanımı ise ” $dir(klasör ismi) ” şeklindedir. Örnek kullanımların olduğu satırın alt kısımda ki kodu, mirc remote kısmına kopyalayıp çalıştırmanız gerekir.

Öğrenilecek Klasör isimleri şunlardır; Desktop(masaüstü), Favorites(sık kullanılanlar), templates, recent (en son kullanılan dosyaların kaydedildiği yer), sendto(gönder), startup(Başlangıç) ve startmenu(Başlat Menusunun bulunduğu klasör)

[code]alias -l fol {
if ($com(dir)) .comclose dir
.comopen dir wscript.shell
if ($comerr(dir)) { echo -a Com Objesi açılamadı! | return }
else {
var %s = $com(dir,SpecialFolders,3,bstr,$1)
return $+($com(dir).result,\)
}
}
alias dir {
if (!$1) echo -a Hedef klasör belirtilmedi!
else {
var %folders = Desktop Favorites templates recent sendto startup startmenu fonts mydocuments
if ($istok(%folders,$1,32)) return $fol($1)
else return Yanlış Klasör Girişi!
}
}[/code]

Bu hazır kod ile op olduğunuz kanallarda, yazılan satırlar içinde aşırı derecede büyük harf yazımı yapan kullanıcıları banlayıp atmış olursunuz. Bu kod kanalda op olan kullanıcılara işlem yapmayacaktır. Kanalda yazılan satır karakter uzunluğu 15 den büyük olması durumunda çalışır. Bu karakter uzunluğunu, Hazır kod içinde ” if ($len($1-) < 15) ” kısmıda oynama yaparak kendinize göre ayarlayabilirsiniz. Ayrıca yazılan satırda, büyük harf kullanımı ” yüzde 70 ” in üzerinde olan metin yazılarına işlem yaptırmış olursunuz. Bu kısımda kendinize göre düzenleme için kod içinde ” if (%nsohbet >= 0.7) { ” satırında ” 0.7 ” bölümü ile yapabilirsiniz. Bu şekilde ” %70 ” üzeri büyük harf kullanımı yapan kullanıcılar atılmış olacaktır. Mevcut hazır kodu mirc remote kısımına kopyalayınız. Ayrıca büyük harf koruma görüntüsü, uygulamalı olarak kodun altında görebilirsiniz.

[code]on @*:TEXT:*:#: {
if $nick isop $chan { halt }
if ($len($1-) < 15) || ($nick isop #) return
var %text = $strip($remove($1-,$chr(32)))
var %ncs = $len($removecs(%text,A,B,C,D,E,F,G,H,I,J,K,L,M,N,O ,P,Q,R,S,T,U,V,W,X,Y,Z))
var %ns = $len($strip($remove(%text,$chr(32))))
var %nsohbet = $calc(1 - (%ncs / %ns))
if (%nsohbet >= 0.7) {
ban -k $chan $nick 2 2Büyük Harf Kullanımı Yasaktır.Yazmış olduğunuz satırlarda yüzde - $calc(%nsohbet * 100) - oranında büyük harf kullanımı yaptınız.
unset %buyuk. $+ $nick
}
[/code]

Mirc yazışmalarınızda ki nickinizin görünümü normalinde büyük/küçük işaretleri içindedir. Bu Hazır kod ile mirc yazışmalarınızda nickinizin görünümü, ” «nickiniz» ” şeklinde olacaktır. Farklı karekterler belirtirek istediğiniz görünüme getirebilirsiniz. Aşağıda ki hazır kodu mirc remote bölümüne kopyalamanız yeterlidir. Kodu çalıştırdığınız gibi mirc de nick görüntünüz “ «JiX» merhaba Nsohbet Kanalı Sakinleri ” – “ «JiX» Nasılsınız? ” şeklinde olacaktır

[code]

ON *:INPUT:#: {
if (!$inpaste) && ($left($1,1) != $readini(mirc.ini, text, commandchar)) {
echo -t # $+(«,$me,») $iif((c isincs $gettok($chan(#).mode,1,32)),$strip($1-),$1-)
.MSG # $1-
HALT
}
}

ON *:INPUT:#: {
echo –t # $+(«,$me,») $1-
.MSG # $1-
HALT
}[/code]